我模拟的温度应力不对，有人可以看看吗。

可以微信红包100，后续还有问题

!-test1

!有重力加速度

!对称 X=0

!长度10/2

!时间7天

!提取温度差，加载到结构模型，求解温度应力，参考温度为0

!48小时拆模

!浇筑温度为20

!有重力

/clear

*set, day,7           !计算天数，先调试1天

*set, hour, day*24       !计算小时数

*set, BEG_TEMP, 24       !初始温度

*set, air_max, 28        !最高气温 

*set, air_min, 22        !最低气温

*set, l,4             !浇注墙体长度的1/2

*set, h, 3.8             !浇注墙体的高度

*set, t, 0.5             !浇注墙体的厚度 

*set, plank, 0.8         !底板厚

*set, board, 2           !底板宽计算长度 

*set, initial, 20        !底板浇筑温度

*set, houremove, 480     !拆除模版时间 

!!!!!!!!!!!!!!!!!!!!!

/prep7

et,1,solid70

mp,dens,1,2400          !素混凝土容重

mp,kxx,1,8.51           !混凝土的导热系数

mp,c,1,0.944            !混凝土的比热容

!墙体、底板、模板建模

block,,l,0.4,h,,-t             !墙体X长L-0，Y高H-0.4，Z厚-T

block,,l,0.4,0,,-t             !高0.4墙体X长L-0，Y高-0.4， Z厚-T

block,,l,-plank,0,0,-t         !墙体下的底板X长L-0，Y高PLANK，Z厚-T

block,,l,-plank,0,-t,-board    !X长L-0，Y高PLANK，Z厚T-BOARD

!把已建立的体连接起来，同时创建模板

vglue, 1,2

vglue, 3,5

vglue, 3,4

!墙体及底板分网,宽度方向分5份;长度方向分成35*3/2份;高度分16份

lsel,s,length,,t,t           !选择长度为t的线

lesize,all,,,4               !划分为4等分 

lsel,s,length,,l,l           !选择长度为l的线

lesize,all,0.3,             !单元长度0.3m 

lsel,s,length,,h-0.4,h-0.4   !选择长度为h-0.4的线

lesize,all,,,16              !划分为16等分 

lsel,s,length,,0.4,0.4       !选择长度为0.4的线

lesize,all,,,2               !划分为2等分 

lsel,s,length,,plank,plank   !选择长度为plank的线

lesize,all,,,2               !划分为2等分

lsel,s,length,,board-t,board-t   !选择长度为board-t的线

lesize,all,,,5               !划分为5等分

vmesh,1

vmesh,2

vmesh,3

vmesh,5

!选中混凝土表面,建立conc1,conc2组合面

allsel

asel,s,,,1

asel,a,,,2

asel,a,,,4

asel,a,,,6

asel,a,,,8

asel,a,,,11

asel,a,,,7

asel,a,,,14

asel,a,,,18

asel,a,,,25

asel,a,,,12

asel,a,,,19

cm,conc1,area    !选中的面组成1组,编号为conc1

!建立对称面约束

allsel

asel,s,loc,x,0   !建立X坐标为0的面

da,all,symm

DTRAN !将实体模型中的约束转换到有限元模型中

*get,n_num,node,,count !得到节点总数

*dim,he,array,hour,n_num !存放节点温度

*dim,t_temp,array,hour,n_num !存放节点温差

*dim,hgen,array,hour,1 !存放单位时间产热

!计算单位时间产热hgen(i)

*do, i, 1, hour

HE00=330*536*(1-exp(-0.69*(i/24)**0.56))

HE01=330*536*(1-exp(-0.69*(((i+1)/24))**0.56))

*set,hgen(i),HE01-HE00

*enddo

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!求解

/SOLU

ANTYPE,TRANSIENT,NEW   !定义分析类型

nropt, full    

allsel, all      !

nsel,s,,,all     !选所有节点

ic,all,temp,initial   !初始温度20

*do, i, 1, hour,1

time,i

timint, on

vsel,s,,,1

eslv,s

BFe,ALL,HGEN,,hgen(i)         !加水化热

cmsel,s,conc1

!在混凝土表面施加对流系数和空气温度

*set,ta,20

!sfa,all,,CONV,53,ta

sfa,all,,CONV,53,air_max/2+air_min/2+(air_max/2-air_min/2)*cos(15*(i-7))

allsel

TRNOPT,FULL

deltim,1,,,1  !

AUTOTS,ON

KBC,0

outres,all,1

solve

!得到节点温差

*do,ii,1,n_num

*get,te,node,ii,temp

*SET,he(i,ii),te  

*if,i,eq,1,then

t_temp(i,ii)=he(i,ii)-initial

*else

t_temp(i,ii)=he(i,ii)-he(i-1,ii)

*endif

*enddo

allsel

*enddo

save

/PREP7 

allsel,all  

sfdele,all,all   !删除节点上的面荷载   

bfdele,all,all   !删除面上的体载荷  

SFEDELE,ALL,ALL,CONV !删对流边界条件 

SFDELE,ALL,CONV 

ETCHG,TTS

mp,dens,999,2400  

mp,prxy,999,0.167 

mp,alpx,999,0.8e-5

mp,ex,999,0.0022696e10  

esel,s,mat,,1   

mpchg,999,all 

 

*SET,Ec,3.25e10 

*dim,exx,array,hour

*do,i,1,hour,1   

exx(i)=(1-exp(-0.28*(i/24)**0.52))*Ec 

*enddo  

*do,i,1,hour,1   

mp,dens,i,2400  

mp,prxy,i,0.167 

mp,alpx,i,0.8e-5

mp,ex,i,exx(i)  

*enddo  

esel,s,mat,,999   

mpchg,1,all 

allsel  

!施加约束

asel,s,loc,x,0

da,all,symm

!da,all,ux,0

nsel,s,loc,x,l

d,all,ux,0

nsel,s,loc,y,-plank

d,all,all

nsel,s,loc,z,0

d,all,uz,0

nsel,s,loc,y,0,10

nsel,r,loc,z,-t

d,all,uz,0

nsel,s,loc,z,-board

d,all,uz,0

FINISH  

/SOL

antype,static 

ALLSEL,ALL 

ACEL,0,9.8,0

allsel,all

outres,all,all  

tref,20

  

*do,HOU,1,hour

time,HOU

*do,j,1,n_num

bf,j,temp,t_temp(hou,j)

!LDREAD,TEMP,,,HOU,,test8,rth,

*enddo

allsel  

vsel,s,,,1

eslv,s,1

!随着时间变化，材料属性变化

mpchg,HOU,all

allsel

solve  

*enddo  

finish